templates/go/flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

{
  description = "Go project template";

  inputs = {
    futils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs";
    pre-commit-hooks = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs = {
        flake-utils.follows = "futils";
        nixpkgs.follows = "nixpkgs";
      };
    };
  };

  outputs =
    { self
    , futils
    , nixpkgs
    , pre-commit-hooks
    }:
    futils.lib.eachDefaultSystem
      (system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };
        pname = "project-name";
        version = "0.0.1";
        tools = with pkgs; [
          # https://github.com/golang/vscode-go/blob/master/docs/tools.md
          delve
          golangci-lint
          gopls
        ];
      in
      rec {
        # `nix build`
        packages."${pname}" = pkgs.buildGoModule {
          inherit pname version;
          src = ./.;
          vendorSha256 = null;
        };
        defaultPackage = packages."${pname}";

        # `nix run`
        apps = {
          "${pname}" = futils.lib.mkApp {
            drv = packages."${pname}";
            exePath = "/bin/changeme";
          };
          default = apps."${pname}";
        };

        # `nix develop`
        checks = {
          pre-commit = pre-commit-hooks.lib.${system}.run {
            src = ./.;
            hooks = {
              nixpkgs-fmt.enable = true;
              yamllint.enable = true;
              govet.enable = true;
              gotest.enable = true;
              gofmt.enable = true;
              staticcheck.enable = true;
            };
            settings = {
              yamllint.relaxed = true;
            };
          };
        };

        devShell = pkgs.mkShell {
          buildInputs = with pkgs; [ go ] ++ tools;
          inherit (self.checks.${system}.pre-commit) shellHook;
        };
      })
    // {
      overlay = final: prev: {
        XXX = self.defaultPackage.${prev.system};
      };
    };
}