nix/mkHomeManagerConfiguration.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

inputs@{ self, ... }:
{ system ? "x86_64-linux"
, username ? "fcuny"
, hostname
, stateVersion ? "22.11"
,
}:
let
  naersk = inputs.naersk.lib."${system}";
in
inputs.home-manager.lib.homeManagerConfiguration {
  modules = [
    "${self}/hosts/${hostname}/home.nix"
    {
      home = {
        username = username;
        homeDirectory = "/home/${username}";
        stateVersion = stateVersion;
      };
      homeage = {
        identityPaths = [ "~/.age/key.txt" ];
        installationType = "activation";
        mount = "/home/${username}/.secrets";
      };
      imports = [ inputs.homeage.homeManagerModules.homeage ];
    }
  ];

  extraSpecialArgs = { inherit inputs self; };

  pkgs = import inputs.nixpkgs {
    inherit system;
    config.allowUnfree = true;
    overlays = [
      inputs.emacs-overlay.overlay
      inputs.nur.overlay
      inputs.naersk.overlay
      inputs.rust.overlays.default
      (final: prev:
        {
          tools = import "${self}/tools" { pkgs = prev; inherit naersk; };
        })
    ];
  };
}