modules/services/grafana/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

{ config, lib, pkgs, ... }:
let
  cfg = config.my.services.grafana;
  secrets = config.age.secrets;
in
{
  options.my.services.grafana = with lib; {
    enable = mkEnableOption "grafana observability stack";
    vhostName = mkOption {
      type = types.str;
      example = "dash.fcuny.net";
      description = "Name for the virtual host";
    };
  };

  config = lib.mkIf cfg.enable {
    services.grafana = {
      enable = true;
      security.adminUser = "fcuny";
      analytics.reporting.enable = false;
      port = 4000;
      provision = {
        enable = true;
        datasources = [{
          name = "prometheus";
          type = "prometheus";
          isDefault = true;
          url = "http://localhost:9090";
        }];
        dashboards = [{
          disableDeletion = true;
          options.path = ./dashboards;
        }];
      };
    };

    services.nginx.virtualHosts."${cfg.vhostName}" = {
      forceSSL = true;
      useACMEHost = cfg.vhostName;
      locations."/" = {
        proxyPass = "http://${config.services.grafana.addr}:${
            toString config.services.grafana.port
          }";
        proxyWebsockets = true;
      };
    };

    security.acme.certs."${cfg.vhostName}" = {
      dnsProvider = "gcloud";
      credentialsFile = secrets."acme/credentials".path;
    };

    my.services.backup = {
      paths = [ "/var/lib/grafana" ];
      exclude = [ "/var/lib/grafana/log/" ];
    };
  };
}