blob: 04b4e1f07b52dfa80d07afa50f9be1cbdee9e2ea (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
{ config, pkgs, lib, ... }:
let
cfg = config.my.services.backup;
excludeArg = with builtins;
with pkgs;
"--exclude-file="
+ (writeText "excludes.txt" (concatStringsSep "\n" cfg.exclude));
in
{
options.my.services.backup = with lib; {
enable = mkEnableOption "Enable backups for this host";
repository = mkOption {
type = types.str;
example = "/data/slow/backups/system";
description = "The repository to back up to";
};
passwordFile = mkOption {
type = types.path;
example = "/var/lib/restic/password.txt";
description = "Read the repository's password from this path";
};
paths = mkOption {
type = with types; listOf str;
default = [ ];
example = [ "/var/lib" "/home" ];
description = "Paths to backup";
};
exclude = mkOption {
type = with types; listOf str;
default = [ ];
example = [
# very large paths
"/var/lib/docker"
"/var/lib/systemd"
"/var/lib/libvirt"
# temporary files created by `cargo` and `go build`
"**/target"
"/home/*/go/bin"
"/home/*/go/pkg"
];
description = "Paths to exclude from backup";
};
pruneOpts = mkOption {
type = with types; listOf str;
default = [
"--keep-last 10"
"--keep-hourly 24"
"--keep-daily 7"
"--keep-weekly 5"
"--keep-monthly 12"
"--keep-yearly 100"
];
example = [ "--keep-last 5" "--keep-weekly 2" ];
description = ''
List of options to give to the `forget` subcommand after a backup.
'';
};
timerConfig = mkOption {
# NOTE: I do not know how to cleanly set the type
default = { OnCalendar = "daily"; };
example = {
OnCalendar = "00:05";
RandomizedDelaySec = "5h";
};
description = ''
When to run the backup. See man systemd.timer for details.
'';
};
user = mkOption {
type = types.str;
default = "root";
description = ''
As which user the backup should run.
'';
example = "postgresql";
};
};
config = lib.mkIf cfg.enable {
services.restic.backups.host = {
# Take care of included and excluded files
paths = cfg.paths;
extraBackupArgs = [ "--verbose=2" ]
++ lib.optional (builtins.length cfg.exclude != 0) excludeArg;
# Take care of creating the repository if it doesn't exist
initialize = true;
inherit (cfg) passwordFile pruneOpts timerConfig repository user;
};
};
}
|
