flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117

{
  description = "personal NixOS configurations";

  inputs = {
    # Nixpkgs, NixOS's official repo
    nixpkgs.url = "github:nixos/nixpkgs/release-22.05";

    futils.url = "github:numtide/flake-utils";

    # We use the unstable nixpkgs repo for some packages.
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixpkgs-unstable";

    emacs-overlay.url = "github:nix-community/emacs-overlay";

    agenix = {
      url = "github:ryantm/agenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nur.url = "github:nix-community/NUR";

    home-manager = {
      url = "github:nix-community/home-manager/release-22.05";
      # We want home-manager to use the same set of nixpkgs as our system.
      inputs.nixpkgs.follows = "nixpkgs";
    };

    pre-commit-hooks = {
      type = "github";
      owner = "cachix";
      repo = "pre-commit-hooks.nix";
      ref = "master";
      inputs = {
        flake-utils.follows = "futils";
        nixpkgs.follows = "nixpkgs";
      };
    };
  };

  # Output config, or config for NixOS system
  outputs = { self, ... }@inputs:
    let
      inherit (inputs.futils.lib) eachSystem system;
      mySystems = [
        system.x86_64-linux
      ];
      eachMySystem = eachSystem mySystems;
      lib = import ./nix { inherit inputs; };
    in
    eachMySystem
      (system:
        let
          pkgs = import inputs.nixpkgs { inherit system; };
          home-manager = inputs.home-manager.defaultPackage."${system}";
          ci = import ./ops/ci { inherit pkgs; };
        in
        rec
        {
          packages = pkgs // {
            inherit home-manager;

            tools = import ./tools { inherit pkgs; };

            users.fcuny = {
              blog = import ./users/fcuny/blog { inherit pkgs; };
              notes = import ./users/fcuny/notes { inherit pkgs; };
              resume = import ./users/fcuny/resume { inherit pkgs; };
            };
          };

          checks = {
            pre-commit = inputs.pre-commit-hooks.lib.${system}.run {
              src = ./.;

              hooks = {
                nixpkgs-fmt = {
                  enable = true;
                };

                shellcheck = {
                  enable = true;
                };
              };
            };
          };

          # `nix run .#ci.format` formats in current directory!
          apps.ci.format = ci.fmt.mkFmtScript self;

          # `nix run .#ci.shellcheck` formats in current directory!
          apps.ci.shellcheck = ci.shell.mkShellCheckScript self;

          devShells = {
            default = pkgs.mkShell {
              name = "NixOS-config";
              buildInputs = with pkgs; [
                gitAndTools.pre-commit
                nixUnstable
                nixfmt
                nixpkgs-fmt
                rnix-lsp
                home-manager
                git
                go
                gopls
              ];
              inherit (self.checks.${system}.pre-commit) shellHook;
            };
          };
        }) // {
      nixosConfigurations = {
        carmel = lib.mkSystem { hostname = "carmel"; };
        aptos = lib.mkSystem { hostname = "aptos"; };
        tahoe = lib.mkSystem { hostname = "tahoe"; };
      };
    };
}